forked from M-Labs/zynq-rs
300 lines
10 KiB
Nix
300 lines
10 KiB
Nix
|
{ lowPrio, newScope, pkgs, lib, stdenv, cmake
|
|||
|
|
, gccForLibs, preLibcCrossHeaders
|
|||
|
|
, libxml2, python3, isl, fetchurl, overrideCC, wrapCCWith, wrapBintoolsWith
|
|||
|
|
, buildLlvmTools # tools, but from the previous stage, for cross
|
|||
|
|
, targetLlvmLibraries # libraries, but from the next stage, for cross
|
|||
|
|
, targetLlvm
|
|||
|
|
# This is the default binutils, but with *this* version of LLD rather
|
|||
|
|
# than the default LLVM version's, if LLD is the choice. We use these for
|
|||
|
|
# the `useLLVM` bootstrapping below.
|
|||
|
|
, bootBintoolsNoLibc ?
|
|||
|
|
if stdenv.targetPlatform.linker == "lld"
|
|||
|
|
then null
|
|||
|
|
else pkgs.bintoolsNoLibc
|
|||
|
|
, bootBintools ?
|
|||
|
|
if stdenv.targetPlatform.linker == "lld"
|
|||
|
|
then null
|
|||
|
|
else pkgs.bintools
|
|||
|
|
}:
|
|||
|
|
|
|||
|
|
let
|
|||
|
|
release_version = "11.1.0";
|
|||
|
|
candidate = ""; # empty or "rcN"
|
|||
|
|
dash-candidate = lib.optionalString (candidate != "") "-${candidate}";
|
|||
|
|
version = "${release_version}${dash-candidate}"; # differentiating these (variables) is important for RCs
|
|||
|
|
targetConfig = stdenv.targetPlatform.config;
|
|||
|
|
|
|||
|
|
fetch = name: sha256: fetchurl {
|
|||
|
|
url = "https://github.com/llvm/llvm-project/releases/download/llvmorg-${version}/${name}-${release_version}${candidate}.src.tar.xz";
|
|||
|
|
inherit sha256;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clang-tools-extra_src = fetch "clang-tools-extra" "18n1w1hkv931xzq02b34wglbv6zd6sd0r5kb8piwvag7klj7qw3n";
|
|||
|
|
|
|||
|
|
llvm_meta = {
|
|||
|
|
license = lib.licenses.ncsa;
|
|||
|
|
maintainers = lib.teams.llvm.members;
|
|||
|
|
|
|||
|
|
# See llvm/cmake/config-ix.cmake.
|
|||
|
|
platforms =
|
|||
|
|
lib.platforms.aarch64 ++
|
|||
|
|
lib.platforms.arm ++
|
|||
|
|
lib.platforms.mips ++
|
|||
|
|
lib.platforms.power ++
|
|||
|
|
lib.platforms.riscv ++
|
|||
|
|
lib.platforms.s390x ++
|
|||
|
|
lib.platforms.wasi ++
|
|||
|
|
lib.platforms.x86;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
tools = lib.makeExtensible (tools: let
|
|||
|
|
callPackage = newScope (tools // { inherit stdenv cmake libxml2 python3 isl release_version version fetch buildLlvmTools; });
|
|||
|
|
mkExtraBuildCommands0 = cc: ''
|
|||
|
|
rsrc="$out/resource-root"
|
|||
|
|
mkdir "$rsrc"
|
|||
|
|
ln -s "${cc.lib}/lib/clang/${release_version}/include" "$rsrc"
|
|||
|
|
echo "-resource-dir=$rsrc" >> $out/nix-support/cc-cflags
|
|||
|
|
'';
|
|||
|
|
mkExtraBuildCommands = cc: mkExtraBuildCommands0 cc + ''
|
|||
|
|
ln -s "${targetLlvmLibraries.compiler-rt.out}/lib" "$rsrc/lib"
|
|||
|
|
ln -s "${targetLlvmLibraries.compiler-rt.out}/share" "$rsrc/share"
|
|||
|
|
'';
|
|||
|
|
|
|||
|
|
bintoolsNoLibc' =
|
|||
|
|
if bootBintoolsNoLibc == null
|
|||
|
|
then tools.bintoolsNoLibc
|
|||
|
|
else bootBintoolsNoLibc;
|
|||
|
|
bintools' =
|
|||
|
|
if bootBintools == null
|
|||
|
|
then tools.bintools
|
|||
|
|
else bootBintools;
|
|||
|
|
|
|||
|
|
in {
|
|||
|
|
|
|||
|
|
libllvm = callPackage ./llvm {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
# `llvm` historically had the binaries. When choosing an output explicitly,
|
|||
|
|
# we need to reintroduce `outputSpecified` to get the expected behavior e.g. of lib.get*
|
|||
|
|
llvm = tools.libllvm;
|
|||
|
|
|
|||
|
|
libllvm-polly = callPackage ./llvm {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
enablePolly = true;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
llvm-polly = tools.libllvm-polly.lib // { outputSpecified = false; };
|
|||
|
|
|
|||
|
|
libclang = callPackage ./clang {
|
|||
|
|
inherit clang-tools-extra_src llvm_meta;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clang-unwrapped = tools.libclang;
|
|||
|
|
|
|||
|
|
clang-polly-unwrapped = callPackage ./clang {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
inherit clang-tools-extra_src;
|
|||
|
|
libllvm = tools.libllvm-polly;
|
|||
|
|
enablePolly = true;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
llvm-manpages = lowPrio (tools.libllvm.override {
|
|||
|
|
enableManpages = true;
|
|||
|
|
python3 = pkgs.python3; # don't use python-boot
|
|||
|
|
});
|
|||
|
|
|
|||
|
|
clang-manpages = lowPrio (tools.libclang.override {
|
|||
|
|
enableManpages = true;
|
|||
|
|
python3 = pkgs.python3; # don't use python-boot
|
|||
|
|
});
|
|||
|
|
|
|||
|
|
# disabled until recommonmark supports sphinx 3
|
|||
|
|
# lldb-manpages = lowPrio (tools.lldb.override {
|
|||
|
|
# enableManpages = true;
|
|||
|
|
# python3 = pkgs.python3; # don't use python-boot
|
|||
|
|
# });
|
|||
|
|
|
|||
|
|
# pick clang appropriate for package set we are targeting
|
|||
|
|
clang =
|
|||
|
|
/**/ if stdenv.targetPlatform.libc == null then tools.clangNoLibc
|
|||
|
|
else if stdenv.targetPlatform.useLLVM or false then tools.clangUseLLVM
|
|||
|
|
else if (pkgs.targetPackages.stdenv or stdenv).cc.isGNU then tools.libstdcxxClang
|
|||
|
|
else tools.libcxxClang;
|
|||
|
|
|
|||
|
|
libstdcxxClang = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
# libstdcxx is taken from gcc in an ad-hoc way in cc-wrapper.
|
|||
|
|
libcxx = null;
|
|||
|
|
extraPackages = [
|
|||
|
|
targetLlvmLibraries.compiler-rt
|
|||
|
|
];
|
|||
|
|
extraBuildCommands = mkExtraBuildCommands cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
libcxxClang = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = targetLlvmLibraries.libcxx;
|
|||
|
|
extraPackages = [
|
|||
|
|
libcxx.cxxabi
|
|||
|
|
targetLlvmLibraries.compiler-rt
|
|||
|
|
];
|
|||
|
|
extraBuildCommands = mkExtraBuildCommands cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
lld = callPackage ./lld {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
lldb = callPackage ../common/lldb.nix {
|
|||
|
|
src = fetch "lldb" "1vlyg015dyng43xqb8cg2l6r9ix8klibxsajazbfnckdnh54hwxj";
|
|||
|
|
patches = [
|
|||
|
|
./lldb/procfs.patch
|
|||
|
|
./lldb/gnu-install-dirs.patch
|
|||
|
|
];
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
# Below, is the LLVM bootstrapping logic. It handles building a
|
|||
|
|
# fully LLVM toolchain from scratch. No GCC toolchain should be
|
|||
|
|
# pulled in. As a consequence, it is very quick to build different
|
|||
|
|
# targets provided by LLVM and we can also build for what GCC
|
|||
|
|
# doesn’t support like LLVM. Probably we should move to some other
|
|||
|
|
# file.
|
|||
|
|
|
|||
|
|
bintools-unwrapped = callPackage ../common/bintools.nix { };
|
|||
|
|
|
|||
|
|
bintoolsNoLibc = wrapBintoolsWith {
|
|||
|
|
bintools = tools.bintools-unwrapped;
|
|||
|
|
libc = preLibcCrossHeaders;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
bintools = wrapBintoolsWith {
|
|||
|
|
bintools = tools.bintools-unwrapped;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clangUseLLVM = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = targetLlvmLibraries.libcxx;
|
|||
|
|
bintools = bintools';
|
|||
|
|
extraPackages = [
|
|||
|
|
libcxx.cxxabi
|
|||
|
|
targetLlvmLibraries.compiler-rt
|
|||
|
|
] ++ lib.optionals (!stdenv.targetPlatform.isWasm) [
|
|||
|
|
targetLlvmLibraries.libunwind
|
|||
|
|
];
|
|||
|
|
extraBuildCommands = ''
|
|||
|
|
echo "-rtlib=compiler-rt -Wno-unused-command-line-argument" >> $out/nix-support/cc-cflags
|
|||
|
|
echo "-B${targetLlvmLibraries.compiler-rt}/lib" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + lib.optionalString (!stdenv.targetPlatform.isWasm) ''
|
|||
|
|
echo "--unwindlib=libunwind" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + lib.optionalString (!stdenv.targetPlatform.isWasm && stdenv.targetPlatform.useLLVM or false) ''
|
|||
|
|
echo "-lunwind" >> $out/nix-support/cc-ldflags
|
|||
|
|
'' + lib.optionalString stdenv.targetPlatform.isWasm ''
|
|||
|
|
echo "-fno-exceptions" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + mkExtraBuildCommands cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clangNoLibcxx = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = null;
|
|||
|
|
bintools = bintools';
|
|||
|
|
extraPackages = [
|
|||
|
|
targetLlvmLibraries.compiler-rt
|
|||
|
|
];
|
|||
|
|
extraBuildCommands = ''
|
|||
|
|
echo "-rtlib=compiler-rt" >> $out/nix-support/cc-cflags
|
|||
|
|
echo "-B${targetLlvmLibraries.compiler-rt}/lib" >> $out/nix-support/cc-cflags
|
|||
|
|
echo "-nostdlib++" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + mkExtraBuildCommands cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clangNoLibc = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = null;
|
|||
|
|
bintools = bintoolsNoLibc';
|
|||
|
|
extraPackages = [
|
|||
|
|
targetLlvmLibraries.compiler-rt
|
|||
|
|
];
|
|||
|
|
extraBuildCommands = ''
|
|||
|
|
echo "-rtlib=compiler-rt" >> $out/nix-support/cc-cflags
|
|||
|
|
echo "-B${targetLlvmLibraries.compiler-rt}/lib" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + mkExtraBuildCommands cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clangNoCompilerRt = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = null;
|
|||
|
|
bintools = bintoolsNoLibc';
|
|||
|
|
extraPackages = [ ];
|
|||
|
|
extraBuildCommands = ''
|
|||
|
|
echo "-nostartfiles" >> $out/nix-support/cc-cflags
|
|||
|
|
'' + mkExtraBuildCommands0 cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
clangNoCompilerRtWithLibc = wrapCCWith rec {
|
|||
|
|
cc = tools.clang-unwrapped;
|
|||
|
|
libcxx = null;
|
|||
|
|
bintools = bintools';
|
|||
|
|
extraPackages = [ ];
|
|||
|
|
extraBuildCommands = mkExtraBuildCommands0 cc;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
});
|
|||
|
|
|
|||
|
|
libraries = lib.makeExtensible (libraries: let
|
|||
|
|
callPackage = newScope (libraries // buildLlvmTools // { inherit stdenv cmake libxml2 python3 isl release_version version fetch; });
|
|||
|
|
in {
|
|||
|
|
|
|||
|
|
compiler-rt-libc = callPackage ./compiler-rt {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
stdenv = if (stdenv.hostPlatform.useLLVM or false) || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) || (stdenv.hostPlatform.isRiscV && stdenv.hostPlatform.is32bit)
|
|||
|
|
then overrideCC stdenv buildLlvmTools.clangNoCompilerRtWithLibc
|
|||
|
|
else stdenv;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
compiler-rt-no-libc = callPackage ./compiler-rt {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
stdenv = if (stdenv.hostPlatform.useLLVM or false) || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64)
|
|||
|
|
then overrideCC stdenv buildLlvmTools.clangNoCompilerRt
|
|||
|
|
else stdenv;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
# N.B. condition is safe because without useLLVM both are the same.
|
|||
|
|
compiler-rt = if stdenv.hostPlatform.isAndroid || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) || (stdenv.hostPlatform.libc == "newlib")
|
|||
|
|
then libraries.compiler-rt-libc
|
|||
|
|
else libraries.compiler-rt-no-libc;
|
|||
|
|
|
|||
|
|
stdenv = overrideCC stdenv buildLlvmTools.clang;
|
|||
|
|
|
|||
|
|
libcxxStdenv = overrideCC stdenv buildLlvmTools.libcxxClang;
|
|||
|
|
|
|||
|
|
libcxx = callPackage ./libcxx {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
stdenv = if (stdenv.hostPlatform.useLLVM or false) || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64)
|
|||
|
|
then overrideCC stdenv buildLlvmTools.clangNoLibcxx
|
|||
|
|
else stdenv;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
libcxxabi = callPackage ./libcxxabi {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
stdenv = if (stdenv.hostPlatform.useLLVM or false) || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64)
|
|||
|
|
then overrideCC stdenv buildLlvmTools.clangNoLibcxx
|
|||
|
|
else stdenv;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
libunwind = callPackage ./libunwind {
|
|||
|
|
inherit llvm_meta;
|
|||
|
|
stdenv = if (stdenv.hostPlatform.useLLVM or false) || (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64)
|
|||
|
|
then overrideCC stdenv buildLlvmTools.clangNoLibcxx
|
|||
|
|
else stdenv;
|
|||
|
|
};
|
|||
|
|
|
|||
|
|
openmp = callPackage ./openmp {
|
|||
|
|
inherit llvm_meta targetLlvm;
|
|||
|
|
};
|
|||
|
|
});
|
|||
|
|
noExtend = extensible: lib.attrsets.removeAttrs extensible [ "extend" ];
|
|||
|
|
|
|||
|
|
in { inherit tools libraries release_version; } // (noExtend libraries) // (noExtend tools)
|