nix-scripts/artiq-fast/artiq-board.nix

# Install Vivado in /opt and add to /etc/nixos/configuration.nix:
#  nix.sandboxPaths = ["/opt"];

{ pkgs
, rustPlatform
, vivado ? import ./vivado.nix { inherit pkgs; }
}:

let
  artiqSrc = import ./pkgs/artiq-src.nix { fetchgit = pkgs.fetchgit; };
  artiqpkgs = import ./default.nix { inherit pkgs; };

  fetchcargo-legacy = import ./fetchcargo-legacy.nix {
    inherit (pkgs) stdenv lib cacert git;
    cargo = artiqpkgs.cargo-legacy;
    cargo-vendor = artiqpkgs.cargo-vendor-legacy;
  };
  cargoDeps-legacy = fetchcargo-legacy rec {
    name = "artiq-firmware-cargo-deps";
    src = "${artiqSrc}/artiq/firmware";
    sha256 = (import "${artiqSrc}/artiq/firmware/cargosha256.nix");
  };
  cargoVendored-legacy = pkgs.stdenv.mkDerivation {
    name = "artiq-firmware-cargo-vendored";
    src = cargoDeps-legacy;
    phases = [ "unpackPhase" "installPhase" ];
    installPhase =
      ''
      mkdir -p $out/registry
      cat << EOF > $out/config
        [source.crates-io]
        registry = "https://github.com/rust-lang/crates.io-index"
        replace-with = "vendored-sources"

        [source."https://github.com/m-labs/libfringe"]
        git = "https://github.com/m-labs/libfringe"
        rev = "b8a6d8f"
        replace-with = "vendored-sources"

        [source.vendored-sources]
        directory = "$out/registry"
      EOF
      cp -R * $out/registry
      '';
  };

  cargoDeps = rustPlatform.fetchCargoTarball {
    name = "artiq-firmware-cargo-deps";
    src = "${artiqSrc}/artiq/firmware";
    sha256 = "0hh9x34gs81a8g15abka6a0z1wlankra13rbap5j7ba2r8cz4962";
  };

  cargo-xbuild = rustPlatform.buildRustPackage rec {
    pname = "cargo-xbuild";
    version = "0.6.5";
    src = pkgs.fetchFromGitHub {
      owner = "rust-osdev";
      repo = pname;
      rev = "v${version}";
      sha256 = "18djvygq9v8rmfchvi2hfj0i6fhn36m716vqndqnj56fiqviwxvf";
    };
    cargoSha256 = "13sj9j9kl6js75h9xq0yidxy63vixxm9q3f8jil6ymarml5wkhx8";
  };

  artiq7 = pkgs.lib.strings.versionAtLeast artiqpkgs.artiq.version "7.0";

in
{ target
, variant
, src ? null
, buildCommand ? "python -m artiq.gateware.targets.${target} -V ${variant}"
, extraInstallCommands ? ""
, ... }:

# Board packages are Python modules so that they get added to the ARTIQ Python
# environment, and artiq_flash finds them.
pkgs.python3Packages.toPythonModule (pkgs.stdenv.mkDerivation rec {
  name = "artiq-board-${target}-${variant}-${version}";
  version = import ./pkgs/artiq-version.nix (with pkgs; { inherit stdenv fetchgit git; });
  phases = [ "buildPhase" "checkPhase" "installPhase" ];
  nativeBuildInputs = [ vivado pkgs.gnumake ]
    ++ (if artiq7
      then [
        rustPlatform.rust.rustc
        rustPlatform.rust.cargo
        pkgs.llvmPackages_11.clang-unwrapped
        pkgs.llvm_11
        pkgs.lld_11
        rustPlatform.cargoSetupHook
        cargo-xbuild
      ] else [
        artiqpkgs.cargo-legacy
        artiqpkgs.rustc-legacy
        artiqpkgs.binutils-or1k
        artiqpkgs.llvm-or1k
      ]);
  buildInputs = [ (pkgs.python3.withPackages(ps: with ps; [ artiqpkgs.migen artiqpkgs.microscope artiqpkgs.misoc artiqpkgs.jesd204b artiqpkgs.artiq ] ++ (pkgs.lib.optional artiq7 jsonschema))) ];
  buildPhase = if artiq7
    then
      ''
      ARTIQ_PATH=`python -c "import artiq; print(artiq.__path__[0])"`
      ln -s $ARTIQ_PATH/firmware/Cargo.lock .
      cargoDeps=${cargoDeps}
      cargoSetupPostUnpackHook
      cargoSetupPostPatchHook
      export TARGET_AR=llvm-ar
      ${buildCommand}
      ''
    else
      ''
      export CARGO_HOME=${cargoVendored-legacy}
      export TARGET_AR=or1k-linux-ar
      ${buildCommand}
      '';
  # temporarily disabled because there is currently always at least one Kasli bitstream
  # that fails timing and blocks the conda channel.
  doCheck = artiq7;
  checkPhase = ''
    # Search for PCREs in the Vivado output to check for errors
    check_log() {
      grep -Pe "$1" artiq_${target}/${variant}/gateware/vivado.log && exit 1 || true
    }
    check_log "\d+ constraint not met\."
    check_log "Timing constraints are not met\."
    '';
  installPhase =
    ''
    TARGET_DIR=$out/${pkgs.python3Packages.python.sitePackages}/artiq/board-support/${target}-${variant}
    mkdir -p $TARGET_DIR
    cp artiq_${target}/${variant}/gateware/top.bit $TARGET_DIR
    if [ -e artiq_${target}/${variant}/software/bootloader/bootloader.bin ]
    then cp artiq_${target}/${variant}/software/bootloader/bootloader.bin $TARGET_DIR
    fi
    if [ -e artiq_${target}/${variant}/software/runtime ]
    then cp artiq_${target}/${variant}/software/runtime/runtime.{elf,fbi} $TARGET_DIR
    else cp artiq_${target}/${variant}/software/satman/satman.{elf,fbi} $TARGET_DIR
    fi
    ${extraInstallCommands}
    '';
  # don't mangle ELF files as they are not for NixOS
  dontFixup = true;
})