{
  # unstable for kicad 9.0
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  outputs =
    {
      nixpkgs,
      ...
    }:
    let
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
      kicad-project-name = "cxp_sfp";
      kicad-main-version = 9;
    in
    {
      formatter.x86_64-linux = pkgs.nixfmt-rfc-style;
      devShells.${system}.default = pkgs.mkShell {
        name = "kicad-dev-shell";
        packages = [
          pkgs.kicad
        ];
      };
      packages.${system}.default = pkgs.stdenv.mkDerivation {
        name = "project-output";
        src = ./src;
        nativeBuildInputs = [ pkgs.kicad ];

        installPhase = ''
          # fix "/homeless-shelter cannot be created" error
          # see https://github.com/NixOS/nix/issues/670#issuecomment-1211700127
          export HOME=$(pwd)
          export KICAD${builtins.toString kicad-main-version}_3DMODEL_DIR=${pkgs.kicad.libraries.packages3d}/share/kicad/3dmodels

          mkdir -p $out
          kicad-cli jobset run ./${kicad-project-name}.kicad_pro -f ./${kicad-project-name}.kicad_jobset
          cp -r ./result/* $out
        '';
      };
    };
}