kirdy-firmware/flake.nix

{
  description = "Firmware for kirdy";

  inputs.nixpkgs.url = github:NixOS/nixpkgs/nixos-23.11;
  inputs.mozilla-overlay = { url = github:mozilla/nixpkgs-mozilla; flake = false; };

  outputs = { self, nixpkgs, mozilla-overlay }:
    let
      pkgs = import nixpkgs { system = "x86_64-linux"; overlays = [ (import mozilla-overlay) ]; };
      rustManifest = pkgs.fetchurl {
        url = "https://static.rust-lang.org/dist/2024-03-21/channel-rust-nightly.toml";
        sha256 = "1c7db6ab80d20682b5cc5bda7360c63311d7188c0c082902d3790820527cd4e0";
      };

      targets = [
        "thumbv7em-none-eabihf"
      ];
      rustChannelOfTargets = _channel: _date: targets:
        (pkgs.lib.rustLib.fromManifestFile rustManifest {
          inherit (pkgs) stdenv lib fetchurl patchelf;
          }).rust.override {
          inherit targets;
          extensions = ["rust-src"];
        };
      rust = rustChannelOfTargets "nightly" null targets;
      rustPlatform = pkgs.recurseIntoAttrs (pkgs.makeRustPlatform {
        rustc = rust;
        cargo = rust;
      });
      kirdy = rustPlatform.buildRustPackage rec {
        name = "kirdy";
        version = "0.0.0";

        src = self;
        cargoLock = { 
          lockFile = ./Cargo.lock;
        };

        nativeBuildInputs = [ pkgs.llvm ];

        buildPhase = ''
          cargo build --release --bin kirdy
        '';

        installPhase = ''
          mkdir -p $out $out/nix-support
          cp target/thumbv7em-none-eabihf/release/kirdy $out/kirdy.elf
          echo file binary-dist $out/kirdy.elf >> $out/nix-support/hydra-build-products
          llvm-objcopy -O binary target/thumbv7em-none-eabihf/release/kirdy $out/kirdy.bin
          echo file binary-dist $out/kirdy.bin >> $out/nix-support/hydra-build-products
        '';

        dontFixup = true;
        auditable = false;
      };

      pglive = pkgs.python3Packages.buildPythonPackage rec {
        pname = "pglive";
        version = "0.7.2";
        format = "pyproject";
        src = pkgs.fetchPypi {
          inherit pname version;
          hash = "sha256-jqj8X6H1N5mJQ4OrY5ANqRB0YJByqg/bNneEALWmH1A=";
        };
        buildInputs = [ pkgs.python3Packages.poetry-core ];
        propagatedBuildInputs = with pkgs.python3Packages; [ pyqtgraph numpy ];
      };

      kirdy_gui = pkgs.python3Packages.buildPythonPackage {
        pname = "kirdy_gui";
        version = "0.0.0";
        format = "pyproject";
        src = "${self}/pykirdy";

        nativeBuildInputs = [ pkgs.qt6.wrapQtAppsHook ];
        propagatedBuildInputs = [ pkgs.qt6.qtbase ] ++ (with pkgs.python3Packages; [ pyqtgraph pyqt6 qasync pglive aenum]);

        dontWrapQtApps = true;
        postFixup = ''
          wrapQtApp "$out/bin/tec_qt"
        '';
      };
    in {
      packages.x86_64-linux = {
        inherit kirdy;
      };

      hydraJobs = {
        inherit kirdy;
      };

      devShell.x86_64-linux = pkgs.mkShell {
        name = "kirdy-dev-shell";
        buildInputs = with pkgs; [
          rust openocd dfu-util glibc
          ] ++ (with python3Packages; [
            numpy matplotlib pyqtgraph setuptools pyqt6 qasync pglive aenum
          ]);
          shellHook=
          ''
            export QT_PLUGIN_PATH=${pkgs.qt6.qtbase}/${pkgs.qt6.qtbase.dev.qtPluginPrefix}
            export QML2_IMPORT_PATH=${pkgs.qt6.qtbase}/${pkgs.qt6.qtbase.dev.qtQmlPrefix}
          '';
      };
      defaultPackage.x86_64-linux = kirdy;
    };
}