kirdy/flake.nix

{
  description = "Firmware for kirdy";

  inputs.nixpkgs.url = github:NixOS/nixpkgs/1e5b653dff12029333a6546c11e108ede13052eb;
  inputs.mozilla-overlay = { url = github:mozilla/nixpkgs-mozilla; flake = false; };
  inputs.rust-overlay.url = "github:oxalica/rust-overlay";

  outputs = { self, nixpkgs, mozilla-overlay, rust-overlay}:
    let
      pkgs = import nixpkgs { system = "x86_64-linux"; overlays = [ (import mozilla-overlay) (import rust-overlay)]; };
      rust = pkgs.rust-bin.nightly."2024-03-21".default.override{
        extensions = [ "rust-src" ];
        targets = [ "thumbv7em-none-eabihf" ];
      };

      rustPlatform = pkgs.recurseIntoAttrs (pkgs.makeRustPlatform {
        rustc = rust;
        cargo = rust;
      });
      kirdy = rustPlatform.buildRustPackage rec {
        name = "kirdy";
        version = "0.0.0";

        src = self;
        cargoLock = { 
          lockFile = ./Cargo.lock;
        };

        nativeBuildInputs = [ pkgs.llvm ];

        buildPhase = ''
          export BUILD_REVISION=${toString (self.shortRev or self.dirtyShortRev or "unknown")}
          cargo build --release --bin kirdy
        '';

        installPhase = ''
          mkdir -p $out $out/nix-support
          cp target/thumbv7em-none-eabihf/release/kirdy $out/kirdy.elf
          echo file binary-dist $out/kirdy.elf >> $out/nix-support/hydra-build-products
          llvm-objcopy -O binary target/thumbv7em-none-eabihf/release/kirdy $out/kirdy.bin
          echo file binary-dist $out/kirdy.bin >> $out/nix-support/hydra-build-products
        '';

        dontFixup = true;
        auditable = false;
      };

      pglive = pkgs.python3Packages.buildPythonPackage rec {
        pname = "pglive";
        version = "0.8.3";
        format = "pyproject";
        src = pkgs.fetchPypi {
          inherit pname version;
          hash = "sha256-b41ATaYmkt5BtRhhr2qwiwV46a7e2taqJVt93cVSa2k=";
        };
        buildInputs = [ pkgs.python3Packages.poetry-core ];
        propagatedBuildInputs = with pkgs.python3Packages; [ pyqtgraph numpy ];
      };

      pykirdy = pkgs.python3Packages.buildPythonPackage {
        pname = "pykirdy";
        version = "0.0.0";
        format = "pyproject";
        src = "${self}/pykirdy";

        nativeBuildInputs = [ pkgs.qt6.wrapQtAppsHook pkgs.python3Packages.setuptools ];
        propagatedBuildInputs =
          [ pkgs.qt6.qtbase ]
          ++ (with pkgs.python3Packages; [
            numpy
            pyqtgraph
            pyqt6
            qasync
            pglive
          ]);

        dontWrapQtApps = true;
        postFixup = ''
          wrapQtApp "$out/bin/kirdy_qt"
        '';
      };

    in {
      packages.x86_64-linux = {
        inherit kirdy pykirdy;
        default = kirdy;
      };

      apps.x86_64-linux.kirdy_gui = {
        type = "app";
        program = "${self.packages.x86_64-linux.pykirdy}/bin/kirdy_qt";
      };

      hydraJobs = {
        inherit kirdy;
      };

      devShell.x86_64-linux = pkgs.mkShell {
        name = "kirdy-dev-shell";
        buildInputs = with pkgs; [
          rust openocd dfu-util glibc
          ] ++ (with python3Packages; [
            numpy matplotlib pyqtgraph setuptools pyqt6 qasync pglive sipyco
          ]);
          shellHook=
          ''
            export QT_PLUGIN_PATH=${pkgs.qt6.qtbase}/${pkgs.qt6.qtbase.dev.qtPluginPrefix}
            export QML2_IMPORT_PATH=${pkgs.qt6.qtbase}/${pkgs.qt6.qtbase.dev.qtQmlPrefix}
          '';
      };
      defaultPackage.x86_64-linux = kirdy;
    };
}